2009 год 1 тур

Требования

Крупная компания, представляющая собой группу взаимосвязанных организаций (порядка 100), ведет бухгалтерский учет в единой информационной базе в программе «1С:Бухгалтерия 8». Многофирменный учет организован с использованием измерения регистра бухгалтерии «Организации». (В версии 7.7 многофирменный учет организован при помощи разделителя учета "Организации").

Среди операций, проводимых между организациями, имеют место взаимные перечисления денежных средств – внутренние платежи.

Операция перечисления денежных средств у организации-плательщика  отражается проводкой д-т 79 «Внутренние расчеты» - кр-т 51 «Расчетный счет», а у организации-получателя  -  проводкой д-т 51 – кр-т 79 на такую же сумму.

На счете 79 ведется аналитический учет  по субконто «Организации».

Значения измерения «Организации», также как и субконто «Организации» определяются в едином справочнике «Организации».

Руководство компании принимает решение послать в организации компании ревизоров для проведения тотальной выездной проверки всех внутренних платежей, совершенных за некоторый период. Для проверки  всех внутренних платежей, совершенных между двумя организациями, ревизору  достаточно  посетить только одну из этих организаций.

Необходимо  на основании анализа ИБ бухгалтерского учета за заданный период определить, в какие организации следует направить ревизоров, чтобы обеспечить одновременную проверку всех внутренних платежей за данный период минимальным количеством ревизоров. При этом важен только лишь факт наличия операций, а количество операций, проведенных организациями, и суммы перечислений, роли не играют.

Например, если организация X получала (перечисляла) деньги от организации Y и получала (перечисляла) деньги от организации  Z, то для проверки всех внутренних платежей между этими организациями достаточно послать одного ревизора только в одну организацию Х.

Исходные данные представлены в информационной базе каркасной конфигурации, которая содержит

* План счетов бухгалтерского учета, с введенными в него счетами для отражения внутренних платежей на счетах бухгалтерского учета в регистре -бухгалтерии «Журнал операций».
* Справочник «Организации», содержащий наименование организаций, входящих в Группу.
* Документ «Ввод данных» отражающий операции перечисления денежных средств одновременно в системе бухгалтерского учета двух организаций – плательщика и получателя.

Период, за который анализируются операции, задается в форме диалога отчета в виде: «Дата начала -  Дата окончания». По умолчанию должен устанавливаться период, соответствующий 2009 году в целом.

Результат работы программы должен представлять список наименований организаций, которые должны быть посещены ревизорами.  Результат выдать в виде отчета следующего вида.

|  |  |  |
| --- | --- | --- |
| № | Код организации | Наименование организации |
| 1 | 103 | Пронто |
| 2 | 93 | Пунто |
| 3 | 13 | Паронто |

Решение

Рассмотрим пример (так как важен лишь факт наличия операции между двумя организациями, начальные данные представим в виде связей платежей и получений):

|  |  |
| --- | --- |
| Платежи | Получения |
| 02-01 | 01-02 |
| 03-02 | 02-03 |
| 05-02 | 02-05 |
| 06-05 | 05-06 |
| 04-05 | 05-04 |
| 03-05 | 05-03 |

Теперь представим данные в виде взаиморасчетов организаций (проведем соответствие каждой организации, с теми, с которыми идут расчеты):

|  |  |
| --- | --- |
| Организация | Связи |
| 01 | 02 |
| 02 | 01 |
| 03 |
| 05 |
| 03 | 02 |
| 05 |
| 04 | 05 |
| 05 | 02 |
| 03 |
| 04 |
| 06 |
| 06 | 05 |

Теперь следуем следующему алгоритму: пока есть не посещенные организации, посещаем ту, которая имеет больше всех связей и отмечаем те организации, с которыми данная организация связывается, если у организации связи кроме посещенной нет больше организаций – считаем организацию посещенной. Рассмотрим таблицу (выделенные жирным организации – посещенные, выделенные курсивом связи – уже проверенные, подчеркнутые организации – те организации, проводки которых проверены при посещении другой организации):

|  |  |  |
| --- | --- | --- |
| Итерация | Организация | Связи |
| 1 | 01 | 02 |
| 02 | 01 |
| 03 |
| 05 |
| 03 | 02 |
| 05 |
| 04 | 05 |
| 05 | 02 |
| 03 |
| 04 |
| 06 |
| 06 | 05 |
| У организации 05 максимальное количество связей – посещаем её, и проверяем организации-связи, требуется ли их посещать, по причине наличия связей с другими организациями | | |
| 2 | 01 | 02 |
| 02 | 01 |
| 03 |
| *05* |
| 03 | 02 |
| *05* |
| 04 | *05* |
| **05** | *02* |
| *03* |
| *04* |
| *06* |
| 06 | *05* |
| После посещения организации 05 отпала необходимость в посещении организаций 04 и 06, выбираем новую организацию для посещения (по количеству связей) – это организация 02 (осталось 2 не проверенные связи – 01 и 03), посещаем её | | |
| 3 | 01 | *02* |
| **02** | *01* |
| *03* |
| *05* |
| 03 | *02* |
| *05* |
| 04 | *05* |
| **05** | *02* |
| *03* |
| *04* |
| *06* |
| 06 | *05* |
| После посещения организации 02 проводки организаций 01 и 03 тоже считаются проверенными | | |

В результате решение найдено – требуется посетить организации 05 и 02, чтобы проверить все взаиморасчеты.

Реализация

Процедура КнопкаСформироватьНажатие(Кнопка)

ТабДок = ЭлементыФормы.ПолеТабличногоДокумента1;

Макет = ПолучитьМакет("Макет");

ОбластьЗаголовок = Макет.ПолучитьОбласть("Заголовок");

ОбластьДанные = Макет.ПолучитьОбласть("Данные");

Взаимосвязи = Новый Соответствие;

Обход = Новый Массив;

// организации должники

Запрос = Новый Запрос;

Запрос.Текст = "ВЫБРАТЬ

| ЖурналОперацийДвиженияССубконто.Организации КАК Организация1,

| ЖурналОперацийДвиженияССубконто.СубконтоДт1 КАК Организация2

|ИЗ

| РегистрБухгалтерии.ЖурналОпераций.ДвиженияССубконто КАК ЖурналОперацийДвиженияССубконто

|ГДЕ

| ЖурналОперацийДвиженияССубконто.СчетДт.Код = ""79""

|

|УПОРЯДОЧИТЬ ПО

| ЖурналОперацийДвиженияССубконто.Организации";

Результат = Запрос.Выполнить();

Выборка = Результат.Выбрать();

Пока Выборка.Следующий() Цикл

ДобавитьВзаимосвязь(Взаимосвязи,Выборка);

КонецЦикла;

// организации кредиторы

Запрос = Новый Запрос;

Запрос.Текст = "ВЫБРАТЬ

| ЖурналОперацийДвиженияССубконто.Организации КАК Организация1,

| ЖурналОперацийДвиженияССубконто.СубконтоКт1 КАК Организация2

|ИЗ

| РегистрБухгалтерии.ЖурналОпераций.ДвиженияССубконто КАК ЖурналОперацийДвиженияССубконто

|ГДЕ

| ЖурналОперацийДвиженияССубконто.СчетДт.Код = ""51""

|

|УПОРЯДОЧИТЬ ПО

| ЖурналОперацийДвиженияССубконто.Организации";

Результат = Запрос.Выполнить();

Выборка = Результат.Выбрать();

Пока Выборка.Следующий() Цикл

ДобавитьВзаимосвязь(Взаимосвязи,Выборка);

КонецЦикла;

Пока Взаимосвязи.Количество() > 0 Цикл

Максимальный = Неопределено;

Для Каждого Запись Из Взаимосвязи Цикл

Если Максимальный = Неопределено Тогда

Максимальный = Запись;

ИначеЕсли Максимальный.Значение.Количество() < Запись.Значение.Количество() Тогда

Максимальный = Запись;

КонецЕсли;

КонецЦикла;

Обход.Добавить(Максимальный.Ключ);

Для Каждого Связь Из Максимальный.Значение Цикл

Взаимосвязь = Взаимосвязи.Получить(Связь);

Индекс = Взаимосвязь.Найти(Максимальный.Ключ);

Взаимосвязь.Удалить(Индекс);

Если Взаимосвязь.Количество() = 0 Тогда

Взаимосвязи.Удалить(Связь);

КонецЕсли;

КонецЦикла;

Взаимосвязи.Удалить(Максимальный.Ключ);

КонецЦикла;

ТабДок.Очистить();

ТабДок.Вывести(ОбластьЗаголовок);

Номер = 1;

Для Каждого Организация Из Обход Цикл

ОбластьДанные.Параметры[0] = Номер;

ОбластьДанные.Параметры[1] = Организация.Код;

ОбластьДанные.Параметры[2] = Организация.Наименование;

ТабДок.Вывести(ОбластьДанные);

Номер = Номер + 1;

КонецЦикла;

КонецПроцедуры

Процедура ДобавитьВзаимосвязь(Взаимосвязи,Выборка)

Взаимосвязи1 = Взаимосвязи.Получить(Выборка.Организация1);

Взаимосвязи2 = Взаимосвязи.Получить(Выборка.Организация2);

Если Взаимосвязи1 = Неопределено Тогда

Взаимосвязи1 = Новый Массив;

Взаимосвязи.Вставить(Выборка.Организация1,Взаимосвязи1);

КонецЕсли;

Если Взаимосвязи2 = Неопределено Тогда

Взаимосвязи2 = Новый Массив;

Взаимосвязи.Вставить(Выборка.Организация2,Взаимосвязи2);

КонецЕсли;

Если Взаимосвязи1.Найти(Выборка.Организация2) = Неопределено Тогда

Взаимосвязи1.Добавить(Выборка.Организация2);

КонецЕсли;

Если Взаимосвязи2.Найти(Выборка.Организация1) = Неопределено Тогда

Взаимосвязи2.Добавить(Выборка.Организация1);

КонецЕсли;

КонецПроцедуры

Автор: Михайлов Алексей

Пояснения к коду:

ТабДок = ЭлементыФормы.ПолеТабличногоДокумента1;

Макет = ПолучитьМакет("Макет");

ОбластьЗаголовок = Макет.ПолучитьОбласть("Заголовок");

ОбластьДанные = Макет.ПолучитьОбласть("Данные");

Взаимосвязи = Новый Соответствие;

Обход = Новый Массив;

В данном блоке идет получение поля табличного документа, для вывода результата, получение макета, для построения таблицы результата, областей макета и создание массива с результатом – Обход, который будет содержать организации, которые требуется посетить для проверок всех взаиморасчетов, и создание соответствия Взаимосвязи, для хранения организаций с их связями.

Запрос = Новый Запрос;

Запрос.Текст = "ВЫБРАТЬ

| ЖурналОперацийДвиженияССубконто.Организации КАК Организация1,

| ЖурналОперацийДвиженияССубконто.СубконтоДт1 КАК Организация2

|ИЗ

| РегистрБухгалтерии.ЖурналОпераций.ДвиженияССубконто КАК ЖурналОперацийДвиженияССубконто

|ГДЕ

| ЖурналОперацийДвиженияССубконто.СчетДт.Код = ""79""

|

|УПОРЯДОЧИТЬ ПО

| ЖурналОперацийДвиженияССубконто.Организации";

Результат = Запрос.Выполнить();

Выборка = Результат.Выбрать();

Пока Выборка.Следующий() Цикл

ДобавитьВзаимосвязь(Взаимосвязи,Выборка);

КонецЦикла;

В данном блоке идет получение платежей из базы данных, и результаты выполнения запроса добавляются в соответствие Взаимосвязи.

Запрос = Новый Запрос;

Запрос.Текст = "ВЫБРАТЬ

| ЖурналОперацийДвиженияССубконто.Организации КАК Организация1,

| ЖурналОперацийДвиженияССубконто.СубконтоКт1 КАК Организация2

|ИЗ

| РегистрБухгалтерии.ЖурналОпераций.ДвиженияССубконто КАК ЖурналОперацийДвиженияССубконто

|ГДЕ

| ЖурналОперацийДвиженияССубконто.СчетДт.Код = ""51""

|

|УПОРЯДОЧИТЬ ПО

| ЖурналОперацийДвиженияССубконто.Организации";

Результат = Запрос.Выполнить();

Выборка = Результат.Выбрать();

Пока Выборка.Следующий() Цикл

ДобавитьВзаимосвязь(Взаимосвязи,Выборка);

КонецЦикла;

В данном блоке так же идет получение платежей и добавление в соответствие Взаимосвязи, но получение идет со счета 51.

Пока Взаимосвязи.Количество() > 0 Цикл

Максимальный = Неопределено;

Для Каждого Запись Из Взаимосвязи Цикл

Если Максимальный = Неопределено Тогда

Максимальный = Запись;

ИначеЕсли Максимальный.Значение.Количество() < Запись.Значение.Количество() Тогда

Максимальный = Запись;

КонецЕсли;

КонецЦикла;

Обход.Добавить(Максимальный.Ключ);

Для Каждого Связь Из Максимальный.Значение Цикл

Взаимосвязь = Взаимосвязи.Получить(Связь);

Индекс = Взаимосвязь.Найти(Максимальный.Ключ);

Взаимосвязь.Удалить(Индекс);

Если Взаимосвязь.Количество() = 0 Тогда

Взаимосвязи.Удалить(Связь);

КонецЕсли;

КонецЦикла;

Взаимосвязи.Удалить(Максимальный.Ключ);

КонецЦикла;

В данном блоке реализован алгоритм, описанный в разделе решение. Пока есть не посещенные организации ищется организация с максимальным количеством связей, добавляется в список посещений и для каждой из связей убирается данная организация из списка организации-связи, а если связей у той организации больше не остается – она не требует посещения и удаляется из соответствия Взаимосвязи.

ТабДок.Очистить();

ТабДок.Вывести(ОбластьЗаголовок);

Номер = 1;

Для Каждого Организация Из Обход Цикл

ОбластьДанные.Параметры[0] = Номер;

ОбластьДанные.Параметры[1] = Организация.Код;

ОбластьДанные.Параметры[2] = Организация.Наименование;

ТабДок.Вывести(ОбластьДанные);

Номер = Номер + 1;

КонецЦикла;

В данном блоке идет очистка табличного документа от старых данных и вывод полученного результата.

Процедура ДобавитьВзаимосвязь(Взаимосвязи,Выборка)

Взаимосвязи1 = Взаимосвязи.Получить(Выборка.Организация1);

Взаимосвязи2 = Взаимосвязи.Получить(Выборка.Организация2);

Если Взаимосвязи1 = Неопределено Тогда

Взаимосвязи1 = Новый Массив;

Взаимосвязи.Вставить(Выборка.Организация1,Взаимосвязи1);

КонецЕсли;

Если Взаимосвязи2 = Неопределено Тогда

Взаимосвязи2 = Новый Массив;

Взаимосвязи.Вставить(Выборка.Организация2,Взаимосвязи2);

КонецЕсли;

Если Взаимосвязи1.Найти(Выборка.Организация2) = Неопределено Тогда

Взаимосвязи1.Добавить(Выборка.Организация2);

КонецЕсли;

Если Взаимосвязи2.Найти(Выборка.Организация1) = Неопределено Тогда

Взаимосвязи2.Добавить(Выборка.Организация1);

КонецЕсли;

КонецПроцедуры

Данная процедура добавляет пару организаций в соответствие Взаимосвязи. При условиях: если нет первой или второй организации в соответствии, то для её связей создается массив и добавляется в соответствие. Если в списке связей организации не найдена вторая – то идет добавление в список связей.

Сформированный отчет

